[Sysadmins MV] Consulta en LDAP AD

Yo no tengo ni idea pero quizás AikonCWD puede que te ayude, si lo lee claro...

#1 Te recomiendo usar powershell, con el módulo de AD puedes hacer de todo.

#6 Ya casi lo tengo... me falta solo alcarar una duda más. Usas NestedGroups en tu ActiveDirectory? Es decir, imagina que tienes un usuario miembro de 2 grupos diferentes (grupo A y grupo y a su vez tienes el grupo B metido dentro de otro grupo (por ejemplo C). Ese tipo de estructuras se llaman NestedGroups. Sería tu caso?

#9 Vale, prueba el siguiente código:

Set oFSO = CreateObject("Scripting.FileSystemObject")
Set oADO = CreateObject("ADODB.Connection")
Set oCMD = CreateObject("ADODB.Command")

oADO.Provider = "ADsDSOObject"
oADO.Open "Active Directory Provider"
Set oCMD.ActiveConnection = oADO

If oFSO.FileExists("output.log") Then oFSO.DeleteFile "output.log"

strLDAP = "LDAP://" & GetObject("LDAP://RootDSE").Get("defaultNamingContext")
oCMD.CommandText = "SELECT distinguishedName, sAMAccountName FROM '" & strLDAP & "' WHERE objectCategory = 'user'"

oCMD.Properties("Page Size") = 1000
oCMD.Properties("Timeout") = 30
oCMD.Properties("Searchscope") = 2
oCMD.Properties("Cache Results") = False

Set RS = oCMD.Execute

RS.MoveFirst
Do Until RS.EOF
	Set objUser		= GetObject("LDAP://" & RS.Fields("distinguishedName"))
	Set oGroups	= objUser.Groups
	writeLog objUser.sAMAccountName
	For Each Group in oGroups
		writeLog " > " & Group.CN
		GetNested(Group)
	Next
	writeLog ""
	RS.MoveNext
Loop

Function GetNested(oGroup)
	On Error Resume Next
	For Each Nest in oGroup.GetEx("memberOf")
		Set oNest = GetObject("LDAP://" & Nest)
		writeLog " >> " & oNest.CN
		GetNested(oNest)
	Next
End Function

Function writeLog(text)
	Set F = oFSO.OpenTextFile("output.log", 8, True)
		F.WriteLine text
	F.Close
End Function

MsgBox "Proceso finalizado correctamente", vbInformation, ""

Copia el texto y lo guardas como listar_usuarios_grupos_nested.vbs, ejecutalo desde el controlador de dominio o desde cualquier equipo del dominio con una sesión de usuarios con permisos sobre el AD.

Espera a que finalice (verás un msgbox informativo) y abre el fichero output.log, verás todos tus usuarios y abajo los grupos a los que pertenece. Los grupos nested estarán indicados por una doble >>. Si puedes, pasame ese output.log en un pastebin (por MP). A partir de ahí, si la información es correcta solo tendremos que meter un par de condiciones y utilizar la función InStr() para devolver solo los grupos deseados

PD: PowerShell es muy potente, pero a mi personalmente no me gusta demasiado, su sintaxis es horrorosa.

#14 La condición para buscar el grupo está repetida en 2 líneas diferentes (because nestedgroups), mira en la líneas 28 y 46. Tal y como te he puesto el ejemplo, el script dumpea los usuarios que esten en uno de esos 2 grupos, si quieres solo los de zaragoza puedes poner:

If (InStr(Group.CN, "GR Curritos Zaragoza") > 0) Or (InStr(Group.CN, "GR Administrativos Zaragoza") > 0) Then
...
...
If (InStr(cn, "GR Curritos Zaragoza") > 0) Or (InStr(cn, "GR Administrativos Zaragoza") > 0) Then

La función writeLog objUser.sAMAccountName ya imprime el username. Si necesitas más datos del usuario tendrás que mirar la documentación de ese objeto:

Puedes probar con writeLog objUser.CN o writeLog objUser.displayName. Lo del grupo tiene un poco más de guasa... ya que cada usuario podría estar en 1, 2, 3, 4, ... N grupos, no? Habría que crear una función que recorra el array de los grupos y los dumpee en la misma línea del TXT/CSV. Si quieres mañana puedo intentar hacertelo. De momento prueba:

writeLog objUser.sAMAccountName & ";" & objUser.CN & ";" & objUser.displayName

Usa la función buscar/reemplazar para cambiar output.log por output.csv

PD: Al final te voy a pasar una factura por mi tiempo xD

EDIT: Tienes que ampliar la consulta LDAP, añadiendo los nuevos campos:

"SELECT distinguishedName, sAMAccountName, CN, displayName FROM '"